startshape HEXROOT

rule HEXROOT {
    STAR {}
}

rule STAR {
    ROSE {}
    SEED {x  17.32  y  10.00 rotate -060}
    SEED {x  17.32  y -10.00 rotate -120}
    SEED {x  00.00  y  20.00 rotate  000}
    SEED {x  00.00  y -20.00 rotate  180}
    SEED {x -17.32  y  10.00 rotate  060}
    SEED {x -17.32  y -10.00 rotate  120}
}

rule SEED {
    TILE1 {}
    TILE2 {x 0.0 y 10.0}
    SEED {x 0.0 y 20.0 rotate -1.5 size 0.95 brightness 0.1 }
}

rule SEED 0.07 {
    SEED {rotate 60}
    SEED {rotate -60}
}

rule ROSE {
    HEXAGON {x  8.6602  y   5.0}
    HEXAGON {x  8.6602  y  -5.0}
    HEXAGON {x  0.0000  y  10.0}
    HEXAGON {x  0.0000  y -10.0}
    HEXAGON {x -8.6602  y   5.0}
    HEXAGON {x -8.6602  y  -5.0}
}

rule TILE1 {
    HEXAGON {x   0.0    y   0.0}
    HEXAGON {x   8.6602 y   5.0}
    HEXAGON {x   8.6602 y  -5.0}
}


rule TILE2 {
    HEXAGON {x   0.0    y   0.0}
    HEXAGON {x  -8.6602 y   5.0}
    HEXAGON {x  -8.6602 y  -5.0}
}


rule HEXAGON {
    SQUARE {rotate  0    size 5  x  0.0     y  1.83}
    SQUARE {rotate  0    size 5  x  0.0     y -1.83}
    SQUARE {rotate  30   size 5  x  1.584   y  0.91506}
    SQUARE {rotate -30   size 5  x  1.584   y -0.91506}
    SQUARE {rotate -30   size 5  x -1.584   y  0.91506}
    SQUARE {rotate  30   size 5  x -1.584   y -0.91506}
}